add something!

Links

• Documentation on ICU regular expressions
• Documentation on the part of the library that deals with regular expressions

Imports and pragmas

{-# LANGUAGE OverloadedStrings #-}

It's better to import the module qualified, because some functions from it (like find and span) clash with those from Prelude. Additionally, many functions clash with ones from Data.Text, so don't import it as T either.

import qualified Data.Text.ICU as ICU

If you want replacement as well:

-- from text-regex-replace
import qualified Data.Text.ICU.Replace as ICU

Search

To search, use findAll (or find if you only need the 1st match):

> ICU.findAll "[0-9]+" "12 + 34 = 55"
[Match ["12"],Match ["34"],Match ["55"]]

findAll returns a list of Matches. A Match holds information about the matched piece of text, groups inside of the match, and text occuring between the matches.

For example, let's construct a regex that would match a name and a surname: (\p{Lu}\w*) (\p{Lu}\w*) – here \w means “character that can occur inside a word”, and \p{Lu} means “character from Unicode category Lu”, which is “Letter, uppercase”:

> let regex = "(\\p{Lu}\\w*) (\\p{Lu}\\w*)"
> let [zaphod, ford] = ICU.findAll regex "Zaphod Beeblebrox and Ford Prefect"

To get the match itself, use group 0 (which will always return Just, but unfortunately the library doesn't provide an easier way to get the match without having to unwrap Just):

> ICU.group 0 ford
Just "Ford Prefect"

You can also use group to get a particular capturing group:

> ICU.group 1 ford
Just "Ford"

> ICU.group 2 ford
Just "Prefect"

span returns the text between the previous match and this match:

> ICU.span ford
" and "

Finally, you can use prefix and suffix to get the whole string before/after the match:

> ICU.prefix 0 ford
Just "Zaphod Beeblebrox and "

> ICU.suffix 0 ford
Just ""

Replacement

Simple replacement is done with replaceAll (to replace only the 1st match, use replace):

> ICU.replaceAll "[0-9]+" "<num>" "12 + 34 = 55"
"<num> + <num> = <num>"

Replacement with groups:

> ICU.replaceAll "(.*), (.*)" "$2 $1" "Beeblebrox, Zaphod"
"Zaphod Beeblebrox"

(To have a literal $ in the output, write $$ instead of $.)

Splitting

text-icu doesn't export a splitting function, which makes it a bit complicated. Here's one that you could use:

split :: ICU.Regex -> Text -> [Text]
split r s = go (ICU.findAll r s)
  where go [] = [s]
        go [m] = [ICU.span m, fromJust (ICU.suffix 0 m)]
        go (m:ms) = ICU.span m : go ms

Regex settings

You can customise the way regexes are applied by using regex and MatchOption. For instance, if you want the matching to be case-insensitive, use CaseInsensitive:

> let regex = ICU.regex [ICU.CaseInsensitive] "xxx_(\\w+)_xxx"
> let str = "xxx_Overlord_xxx XXX_dp_ak_XXX"

> mapMaybe (ICU.group 1) (ICU.findAll regex str)
["Overlord","dp_ak"]

There are other settings available – look at the docs for MatchOption to see the full list.

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!

add something!