When NOT to use do

2018-10-30T17:06:36Z

When NOT to use do

There are a number of situations where using do notation doesn't buy you anything and only results in less concise code. The sections below contain pairs of code blocks that are equivalent where the latter should be preferred.

Single statement do blocks

A do block with a single statement s is equivalent to s on its own.

oneLineDo name = do
  putStrLn ("Hi there " ++ name)

oneLineDoSimplified name = putStrLn ("Hi there " ++ name)

Assignment then return

If the second to last line in a do block is a variable binding (x <- bar) and the last line is return x, they can be replaced by simply bar.

assignAndReturn = do
  x <- bar
  return x

assignAndReturnSimplified = bar

Only bind needed

If the do block consists of a sequence of variable binding via x <- followed by passing x to another function, these can be replaced by monadic function composition using the bind operator >>=.

onlyBindNeeded = do
  x <- getX
  y <- getY x
  return y

onlyBindNeededSimplified = getX >>= getY

Only lift needed:

If the do block consists of a number of variable binding via <- and the last line returns a value constructed from the bindings, prefer using the liftA<n> functions (if your <n> is small) or using applicative style via <$> and <*>.

onlyLiftNeeded :: IO (a, b)
onlyLiftNeeded = do
  a <- getA
  b <- getB
  return (a, b)

onlyLiftNeededLiftA2 :: IO (a, b)
onlyLiftNeededLiftA2 = liftA2 (,) getA getB

onlyLiftNeededApplicativeStyle :: IO (a, b)
onlyLiftNeededApplicativeStyle = (,) <$> getA <*> getB

Do notation – Haskell – Aelve Guide

When NOT to use do

When NOT to use do